;hsqcetfpgpsi2
;avance-version (08/01/15)
;HSQC
;2D H-1/X correlation via double inept transfer
;   using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection
;with decoupling during acquisition
;using flip-back pulse
;with gradients in back-inept
;
;A.G. Palmer III, J. Cavanagh, P.E. Wright & M. Rance, J. Magn.
;   Reson. 93, 151-170 (1991)
;L.E. Kay, P. Keifer & T. Saarinen, J. Am. Chem. Soc. 114,
;   10663-5 (1992)
;J. Schleucher, M. Schwendinger, M. Sattler, P. Schmidt, O. Schedletzky,
;   S.J. Glaser, O.W. Sorensen & C. Griesinger, J. Biomol. NMR 4,
;   301-306 (1994)
;S. Grzesiek & A. Bax, J. Am. Chem. Soc. 115, 12593-12594 (1993)
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


prosol relations=<triple>


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

define list<loopcounter> t1list=<$VCLIST>

"p2=p1*2"
"p4=p3*2"
"p22=p21*2"
"d4=1s/(cnst2*4)"
"d11=30m"

;"d0=3u"

"in0=inf1/2"


"DELTA=p16+d16+p2+d0*2"
"DELTA1=p16+d16+8u"
"DELTA2=d24-p19-d16"
"DELTA3=d4-p16-d16"

"l10=td1/2"

1 ze
  d11 pl12:f2
; this part is for the first point if one records a non-zero first point
20u
  "cnst29=(t1list%2)*180"
  3m ip3+cnst29
  3m ip6+cnst29
  3m ip31+cnst29

2 d11 do:f2
3 6m
5 d1 pl1:f1

  20u
  "d0=in0*t1list+3u"

  (p1 ph1)
  d4 pl2:f2
  (center (p2 ph2) (p4 ph6):f2 )
  d4 UNBLKGRAD
  (p1 ph2) 
  4u pl0:f1
  (p11:sp1 ph1:r):f1
  4u
  p16:gp1
  d16 pl1:f1 pl3:f3
  (p3 ph3):f2
  d0 
  (center (p2 ph7):f1 (p22 ph8):f3)
  d0
  p16:gp2*EA
  d16
  (p4 ph4):f2
  DELTA
  (center (p1 ph1) (p3 ph4):f2 )
  p19:gp4
  d16
  DELTA2
  (center (p2 ph1) (p4 ph1):f2 )
  DELTA2
  p19:gp4
  d16
  (center (p1 ph2) (p3 ph5):f2 )
  p16:gp5
  d16
  DELTA3
  (center (p2 ph1) (p4 ph1):f2 )
  DELTA3
  p16:gp5
  d16
  (p1 ph1)
  DELTA1
  (p2 ph1)
  4u
  p16:gp3
  d16 pl12:f2
  4u BLKGRAD
  go=2 ph31 cpd2:f2
  ;;d1 do:f2 mc #0 to 2 
  ;;   F1EA(igrad EA & ip5*2, id0 & ip3*2 & ip6*2 & ip31*2)
  d11 do:f2 wr #0 if #0 zd

  3m igrad EA
  3m ip5*2

  lo to 2 times 2
  3m rp5 
  3m rp3
  3m rp6
  3m rp31
  3m t1list.inc
20u
  "cnst29=(t1list%2)*180"  ;checking if the next point on schedule is odd or even
  3m ip3+cnst29
  3m ip6+cnst29
  3m ip31+cnst29
   
  lo to 2 times l10
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 2 2
ph5=1 1 3 3
ph6=0
ph7=0 0 2 2
ph8=2
ph31=2 0 0 2
  

;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;sp1: f1 channel - shaped pulse  90 degree
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p11: f1 channel -  90 degree shaped pulse
;p16: homospoil/gradient pulse                         [1 msec]
;p19: gradient pulse 2                                 [500 usec]
;d0 : incremented delay (2D)                           [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4: 1/(4J(YH))
;d11: delay for disk I/O                               [30 msec]
;d16: delay for homospoil/gradient recovery
;d24: 1/(4J)YH for YH
;     1/(8J)YH for all multiplicities
;cnst2: = J(YH)
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence


;use gradient ratio:  gp 1 : gp 2 : gp 3 : gp 4 : gp 5
;                       50 :   80 : 20.1 :    5 :   -2       for C-13
;                       50 :   80 :  8.1 :    5 :   -2       for N-15

;for z-only gradients:
;gpz1: 50%
;gpz2: 80%
;gpz3: 8.1% for N-15, 20.1% for C-13
;gpz4: 5%
;gpz5: -2%

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100
;gpnam4: SINE.100
;gpnam5: SINE.100



;$Id: hsqcetfpgpsi2,v 1.1.2.1 2008/01/15 18:13:12 ber Exp $